Copying -makernotes from ORF to Capture One developed photos (Mac)

[Frediko]

Thanks for your supertool. I tried to find a solution for my problem using the search function but was not successful.

Capture One deletes some of the makernotes written in the Olympus Raw-Files (.ORF) when e.g. a jpeg-File gets developed from the ORF-File. Fortunately C1 may automatically start an Applescript after developing a file. I'd like to use this to copy e.g. the -makernotes from the original .ORF to the developed files.

Let's say the .ORF file is called filename.orf and is situated in a path like ../somename/capture/filename.orf.

The developed e.g. .jpg files are developed to a path like ../somename/output/filename-c1.jpg. A variant of the developed ORF would be ../somename/output/filename-c1 1.jpg, another could be ../somename/output/filename-c1 2.jpg

I know how to read out the filename and the sourcepath of the orf-file and to "calculate" the destinationpath in the Applesript, and the beginning of the ExifTool call from within the AppleScript, like: 

do shell script "/usr/local/bin/exiftool -tagsfromfile " & quoted form of sourcepath & "/" & SrcFile & " -makernotes -all:all " & quoted form of destpath & "/" & ...AND HERE THE PROBLEM STARTS FOR ME

I'd like to know what I have to type in as the destination file name covering all the variants like filename-c1.jpg, filename-c1 1.jpg and filename-c1 2.jpg. Ideally it should work for other file-extensions as well...

Thanks in advance

[StarGeek]

First off, test this out on the command line to make sure it works before using it in a script. 

I believe you'll have to use two separate -TagsFromFile options, of which one will always throw a file not found type error.

Test this out to see if it works
exiftool -TagsFromFile ../capture/%-.5f.orf -makernotes -all:all -TagsFromFile ../capture/%-.3f.orf -makernotes -all:all /path/to/files/

The %-.5f will drop the last five characters in the file name while %-.3f will drop the last three.  Obviously one will fail but the other should succeed.

If your output names end up going past 9, e.g. filename-c1 10.jpg, then you'll require another -TagsFromFile to cut off six characters.

[Hubert]

I always test in Terminal before wrapping my ExifTool commands in AppleScripts, but it looks as though it may be as simple as

exiftool -tagsfromfile sourcepath/filename.orf -makernotes -all:all destpath/filename*

I may be totally wrong, but I think all you'd need to do is parse the root name of the .orf file (without the extension) and then append a *. For me this updates .jpgs and .tiffs with names based on the original raw file (Panasonic .rw2 in my case).

If it works, you may want to add an -overwrite_original tag as well.

[Frediko]

Thanks Hubert and StarGeek. This (just adding the *) works perfectly for me. StarGeek is there any disadvantage of the simple (and at least currently working for me) solution Hubert proposed?

[StarGeek]

I wouldn't know as I don't have a Mac or understand Applescript.  My example would be for doing it in batch on the command line.

[Phil Harvey]

That should work, but note that it will overwrite any metadata in the destination files.  At the very least I might want to add --ext orf to make sure it doesn't try to overwrite ORF files.  Better yet, add -ext jpg and any other extensions that you want to process.

- Phil

[Hubert]

I wouldn't know as I don't have a Mac or understand Applescript.  My example would be for doing it in batch on the command line.

My suggestion was, if you like, pre-AppleScript. I ran the command from Terminal (Mac equivalent of the Windows command line) and it would need some additional wrangling to get it to run in an AS "do shell script" wrapper.

So the * may be a UNIX thing and I don't know if it would work in Windows, but it's not AppleScript.

Thanks Phil for perfecting it.

[Frediko]

Thanks to all of you, the whole Applescript looks like this now:

Code Select Expand


tell application "Capture One 21"

set selectedVariants to get selected variants --the variants selected in Capture One

repeat with i from 1 to number of selected variants --loop thru all variants
set ThisItem to item i of selectedVariants --the current item processed as there might be more than one file selected in Capture One
set SrcFileName to name of (parent image of ThisItem) --Source File Name without path
set SrcFilePath to path of (parent image of ThisItem) --Source File Name with path

--Identify the parent directory of the source's directory
--'Capture' as well as 'Output are in the same parent directory

set AppleScript's text item delimiters to "." --The file's extension is seperated by a "."
set itemCount to (count text items of SrcFileName) --should be two
set FileExt to the last text item of SrcFileName --The file's extension
set FileName to the first text item of SrcFileName --The filename without extension

--display dialog FileExt

set AppleScript's text item delimiters to "/" --The directories are seperated by a "/"
set itemCount to (count text items of SrcFilePath) --should be some
set itemCount to itemCount - 2 --to get the parent directory of the two directories "Capture" and "Output" of a session in Capture One
set parentpath to text 1 thru text item itemCount of SrcFilePath

set sourcepath to parentpath & "/Capture"
set destpath to parentpath & "/Output"

--display dialog "parent: " & parentpath
--display dialog "source: " & sourcepath

do shell script "/usr/local/bin/exiftool -tagsfromfile " & quoted form of sourcepath & "/" & FileName & "." & FileExt & " -makernotes -overwrite_original -all:all --ext orf " & quoted form of destpath & "/" & FileName & "*"

end repeat --end of loop

end tell


I'm sure it might be done more elegant, but it works.